0 REM ***************************
1 REM *      KI-PROGRAMM 1      *
2 REM * 1985 BY MICHAEL NICKLES *
3 REM ***************************
10 REM DATA'S LESEN
20 DIM X(20)
30 FORI=1TO20
40 READ X(I)
50 NEXT I
60 HZ=20: REM ANZAHL DER HOELZER
100 PRINT"[147]VOR IHNEN LIEGT EIN HAEUFCHEN MIT 20    HOELZERN."
110 PRINT"SIE UND DER COMPUTER KOENNEN NUN"
120 PRINT"ABWECHSELND JE 1, 2 ODER 3 HOELZER"
130 PRINT"WEGNEHMEN."
140 PRINT"WER DAS LETZTE HOELZCHEN NEHMEN MUSS,"
150 PRINT"HAT VERLOREN."
220 INPUT"MOECHTEN SIE ANFANGEN (J/N)";I$
230 IFI$<>"J"ANDI$<>"N"THEN220
240 IFI$="J"THENPRINT"OK. SIE FANGEN AN.":GOTO300
250 IFI$="N"THENPRINT"OK. DANN BEGINNE ICH.":GOTO400
300 :
301 REM SPIELER IST AM ZUG
302 :
310 INPUT"WIEVIELE HOELZER";N
320 IFN<>1ANDN<>2ANDN<>3THENPRINT"SIE KOENNEN NUR 1, 2 ODER 3 NEHMEN !":GOTO310
330 HZ=HZ-N
340 IFHZ<=0THENPRINT"SIE HABEN VERLOREN !":END
400 :
401 REM COMPUTER IST AM ZUG
402 :
410 N=X(HZ)
420 PRINT"ICH NEHME";N;"HOELZER."
430 HZ=HZ-N
440 IFHZ=0THENPRINT"SIE HABEN GEWONNEN !":END
500 :
501 REM HOELZERANZAHL FESTLEGEN
502 :
510 PRINT"ES LIEGEN JETZT NOCH";HZ;"HOELZER DA !"
520 GOTO300
1000 DATA1,1,2,3,1,1,2,3,3,1,2,3,2,1,2,3,1,1,2,3